Fitxer:PES1.jpg

De testwiki
Salta a la navegació Salta a la cerca
Fitxer original (1.600 × 1.200 píxels, mida del fitxer: 223 Ko, tipus MIME: image/jpeg)

Aquest fitxer prové de Wikimedia Commons i pot ser usat per altres projectes. La descripció de la seva pàgina de descripció es mostra a continuació.

Resum

Descripció
English: path of electrons in an Angle Resolved Photo Electron Spectroscopy (ARPES) experiment
Data
Font Treball propi
Autor Saiht

script in POVray: 

// Schnitt durch ein PhotoelectronSpetroskopie Experiment
// by Matthias Kreier
#version 0.8;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}

#include "colors.inc"           

camera {
    ultra_wide_angle
    angle 30
    location <30, 30, -45>
    look_at <6, 12, 0>
}               

//plane { <0, 1, 0>, -1 pigment { color Red } }
//plane { <0, 0, -1>, -50 pigment { color White} }
plane { <0.5, 1, -1>, -20 pigment { color LightGray} }

//  ****** Linsensystem zur Fokussierung und Retardierung *******

#declare Linsensystem =
union{ 
 difference{
  union{
    box{<-2.1,3.0,-2.1>,<2.1,3.2,2.1>}
    box{<-2.1,3.4,-2.1>,<2.1,3.6,2.1>}
    box{<-2.1,3.8,-2.1>,<2.1,4.0,2.1>}
    box{<-2.1,6.8,-2.1>,<2.1,7.0,2.1>} 
    pigment { color Blue }   
  }
  cylinder { < 0,2.9,0 > <0,7.1,0> 0.81 pigment { color Silver } }
  cylinder { < 0,2.9,0 > <0,7.1,0> 2 pigment { color Silver } inverse }
 }
 difference{
  union{
    cylinder{ < 0,4.2,0 > <0,4.4,0> 2.1 }
    cylinder{ < 0,4.3,0 > <0,6.5,0> 1.4 }
    cylinder{ < 0,6.4,0 > <0,6.6,0> 2.1 }
    cylinder{ < 0,7.2,0 > <0,7.4,0> 2.1 }
    cylinder{ < 0,7.3,0 > <0,9.9,0> 1.4 }
    cylinder{ < 0,9.8,0 > <0,10,0> 2.1 }
    cylinder{ < 0,10.2,0 > <0,10.4,0> 2.1 }
    cylinder{ < 0,10.3,0 > <0,11.2,0> 1.4 } 
  }
  cylinder { < 0,4.1,0 > <0,11,0> 1.2 pigment { color Silver } }
  cylinder { < 0,10.9,0 > <0,11.3,0> 0.8 pigment { color Silver } }
  cylinder { < 0,4.1,0 > <0,11.3,0> 2 pigment { color Silver } inverse }
 } 
 translate <0,1,0>
}

#declare Kugelanalysator =
union{
 intersection{  // innere Kugel
  difference{
   sphere{<6,14,0>,4.2 pigment{color Silver} }
   sphere{<6,14,0>,4 pigment{color Blue} }
  }
  box{<1,14,0>,<11,19,5> pigment{color Red}}  
 }
 intersection{  // äußere Kugel
  difference{
   sphere{<6,14,0>,8 pigment{color Blue} }
   sphere{<6,14,0>,7.8 pigment{color Silver} }
  }
  box{<-3,14,0>,<15,23,9> pigment{color Red}}  
 }
 difference{  // Herzog-Platte 
  cylinder { < 6,12.5,0 > < 6,13,0 > 9 pigment { color LightSteelBlue } }
  cylinder { < 0,12.4,0>,<0,13.1,0>  1.1 pigment{color Silver}}
  cylinder { < 12,12.4,0>,<12,13.1,0>  2.3 }
 } 
 difference{ 
  cylinder { < 12,12.5,0 > < 12,13.8,0 > 2.4 pigment { color Blue } }
  cylinder { < 12,12.4,0> < 12,13.9,0>  2.2 pigment{color Silver}}  
 }  
 intersection{ // Eingangsspalte
  union{
   box {<-2,13.25,-2>,<2,13.35,2> pigment{color Blue} }
   box {<-0.6,13.3,-2>,<0.6,13.75,2> pigment{color Blue} }
  }
  box {<-0.2,13.2,-2.1>,<0.2,14.1,2.1> pigment{color Silver} inverse}
 }
 intersection{ // Eingangsblenden
  union{
   cylinder { < 0,13.85,0 > < 0,13.9,0 > 2 pigment{color Blue} }
   cylinder { < 0,13.1,0 > < 0,13.15,0 > 2 pigment{color Blue} }
  }
  box {<-0.15,13.0,-1>,<0.15,14.1,1> pigment{color Silver} inverse}
 }

}                 

#declare Scienta =
union{
  object { Linsensystem
           pigment { color Blue }
         } 
  object { Kugelanalysator }
  rotate<0,0,0>
}

intersection{  // Linsensystem und Analysator entlang x aufgeschnitten  
  object { Scienta }
  box{
      <-3,2,0>, <15,23,9> 
      pigment{color Red}
  }
  rotate<0,0,0>
}

intersection{
 union{
  cylinder{<12,13.3,0> <12,13.8,0> 2 pigment{color CadetBlue}}  // Channelplate
  cylinder{<12,13.0,0> <12,13.2,0> 2 pigment{color Green}}  // Phosphorplatte
 }
 box{ <9,10,0>, <15,15,9> pigment{color rgbf <1,1,1,1>}}
}

difference{
  cylinder{<12,9.5,0> <12,11,0> 1.8 pigment{color CadetBlue}}
  cylinder{<12,10 ,0> <12,11.1,0> 1.6 pigment{color Black}}
}
cylinder{<12,9.6,0> <12,8,0> 1.4 pigment{color CadetBlue}}
cylinder{<12,8.1,0> <12,5.5,0> 1.8 pigment{color CadetBlue}}

// *************    Weg der Elektronen  *********
#declare Elektron1 =
union{
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,0,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }                                
 cone { < 0,11,0 >, 0.2, <0,14.1,0>, 0.05 }
 cylinder { < 0,5,0 > <0,11,0> 0.2 } 
 cone { < 0,0,0 >, 0, <0,5,0>, 0.2 }
}

#declare Elektron2 =
union{
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,8,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }                      
 cone { < 0,11,0.9 >, 0.2, <0,14.1,0.9>, 0.05 }
 cylinder { < 0,5.95,0.9 > <0,11,0.9> 0.2 } 
 cone { < 0,0,0 >, 0, <0,6,0.9>, 0.2 }
}

#declare Elektron3 =
union{
 intersection{
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,-10,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }                      
 cone { < 0,11,-0.9 >, 0.2, <0,14.1,-0.9>, 0.05 }
 cylinder { < 0,4.95,-0.9 > <0,11,-0.9> 0.2 } 
 cone { < 0,0,0 >, 0, <0,5,-0.9>, 0.2 }
}

object{ Elektron1 pigment{color rgbf <1,0.8,0,0.8>} }
object{ Elektron2 pigment{color rgbf <1,0.6,0,0.8>} }
object{ Elektron3 pigment{color rgbf <1,1,0,0.8>} }

                         
box{<-1.8,-0.2,-1.8>,<1.8,0,1.8> pigment{color LightSteelBlue}}  // Sample

// einfallender Lichtstrahl He- oder Syncrotron

cylinder{ 
  <-12,12,0> <1,-1,0> 0.5 
  texture{pigment{rgbf<1,1,0.6,0.7>}}
} 
difference{
  cylinder{ <-9.5,9.5.0> <-15,15,0> 1 }
  cylinder{ <-9.4,9.4.0> <-13,13,0> 0.5 }
  pigment { color LightBlue }
}

                         
                        
light_source {
    <12, 18, -200>
    color White
}

light_source {
//    <0, 26, -20>
<30, 30, -45>
    color White
} 

light_source {      // Rückseite beleuchten
    <20, 30, 10>
    color White
}
/*
light_source {      // Kugel innen Licht
    <9, 21, 1.5>
    color White
} 
*/

Llicència

Public domain Jo, el titular del copyright d'aquesta obra, l'allibero al domini públic. Això s'aplica a tot el món.
En alguns països això pot no ser legalment possible, en tal cas:
Jo faig concessió a tothom del dret d'usar aquesta obra per a qualsevol propòsit, sense cap condició llevat d'aquelles requerides per la llei.

Llegendes

Afegeix una explicació d&#039;una línia del que representa aquest fitxer

Elements representats en aquest fitxer

representa l'entitat

Historial del fitxer

Cliqueu una data/hora per veure el fitxer tal com era aleshores.

Data/horaMiniaturaDimensionsUsuari/aComentari
actual15:32, 15 juny 2009Miniatura per a la versió del 15:32, 15 juny 20091.600 × 1.200 (223 Ko)wikimediacommons>Saiht{{Information |Description={{en|1=path of electrons in an Angle Resolved Photo Electron Spectroscopy (ARPES) experiment}} |Source=Own work by uploader |Author=Saiht |Date=2009-06-15 |Permission= |other_versions= }} script in POVray: // Sch

La pàgina següent utilitza aquest fitxer:

Obtingut de «https://ca.wiki.beta.math.wmflabs.org/wiki/Fitxer:PES1.jpg»